refactor: get rid of vars and move common to modules

nixosModules/base/common-nix/default.nix

@@ -0,0 +1,31 @@
+self: {
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib) hasAttr mkIf optionalString;
+
+  inherit (self.inputs) nixpkgs;
+  inherit (config.sops.secrets) access-token;
+
+  cfg = config.roles.base;
+in {
+  config = mkIf cfg.enable {
+    # Minimize dowloads of indirect nixpkgs flakes
+    nix = {
+      registry.nixpkgs.flake = nixpkgs;
+      nixPath = ["nixpkgs=${nixpkgs}"];
+
+      extraOptions =
+        optionalString (hasAttr "sops" config)
+        "!include ${access-token.path}";
+    };
+
+    # Global hm settings
+    home-manager.useGlobalPkgs = true;
+    home-manager.useUserPackages = true;
+  };
+
+  # For accurate stack trace
+  _file = ./default.nix;
+}

nixosModules/base/default.nix

@@ -0,0 +1,155 @@
+self: {
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib) attrValues filter findFirst isAttrs hasAttr mkDefault mkIf mkOption types;
+  inherit (self.inputs) home-manager nh nixd;
+
+  cfg = config.roles.base;
+in {
+  imports = [
+    ./locale
+    ./locate
+    ./substituters
+    (import ./common-nix self)
+    (import ./packages self)
+
+    self.nixosModules.borgbackup
+    self.nixosModules.tmux
+
+    home-manager.nixosModules.home-manager
+  ];
+
+  options.roles.base = {
+    enable = mkOption {
+      type = types.bool;
+      default = true;
+    };
+
+    user = mkOption {
+      type = types.str;
+    };
+  };
+
+  config = mkIf (cfg.enable) {
+    environment.variables.FLAKE = mkDefault "/home/${cfg.user}/.nix";
+
+    programs.tmux.enableCustomConf = true;
+
+    boot.tmp.useTmpfs = true;
+
+    systemd.services.nix-daemon = {
+      environment.TMPDIR = "/home/nix-cache";
+      preStart = ''
+        mkdir -p ${config.systemd.services.nix-daemon.environment.TMPDIR}
+      '';
+    };
+
+    nix = {
+      package = let
+        nixdInput =
+          findFirst
+          (x: x.pname == "nix") {}
+          nixd.packages.${pkgs.system}.nixd.buildInputs;
+
+        throws = x: !(builtins.tryEval x).success;
+        hasVersion = x: isAttrs x && hasAttr "version" x;
+
+        nixVersions = filter (x: ! throws x && hasVersion x) (attrValues pkgs.nixVersions);
+      in
+        findFirst (x: x.version == nixdInput.version) {} nixVersions;
+
+      # Edit nix.conf
+      settings = {
+        # Store
+        keep-outputs = true;
+        keep-derivations = true;
+        auto-optimise-store = true;
+
+        # Commands
+        experimental-features = ["nix-command" "flakes"];
+        http-connections = 0; # unlimited for local cache
+        warn-dirty = false;
+        show-trace = true;
+        allow-import-from-derivation = true;
+
+        # remote building
+        trusted-users = ["matt" "nixremote"];
+      };
+    };
+
+    programs.nh = {
+      enable = true;
+      package = nh.packages.${pkgs.system}.default;
+
+      # weekly cleanup
+      clean = {
+        enable = true;
+        extraArgs = "--keep-since 30d";
+      };
+    };
+
+    services = {
+      fwupd.enable = true;
+
+      xserver.xkb = {
+        layout = "ca";
+        variant = "multix";
+      };
+    };
+
+    boot.supportedFilesystems = ["ext4" "xfs" "btrfs" "vfat" "ntfs"];
+    system.fsPackages = attrValues {
+      inherit
+        (pkgs)
+        btrfs-progs
+        nfs-utils
+        ntfs3g
+        xfsprogs
+        ;
+    };
+
+    environment.variables.NPM_CONFIG_GLOBALCONFIG = "/etc/npmrc";
+    environment.etc.npmrc.text = ''
+      fund = false
+      update-notifier = false
+    '';
+
+    environment.systemPackages = attrValues {
+      # Peripherals
+      inherit
+        (pkgs)
+        hdparm
+        pciutils
+        usbutils
+        rar
+        ;
+    };
+
+    home-manager.users = let
+      default = {
+        imports = [
+          {
+            programs.bash = {
+              sessionVariables = rec {
+                FLAKE = config.environment.variables.FLAKE;
+                NH_FLAKE = FLAKE;
+              };
+              shellAliases.nh = "env -u FLAKE nh";
+            };
+          }
+        ];
+
+        home.stateVersion = config.system.stateVersion;
+      };
+    in {
+      greeter = mkIf (config.services.greetd.enable) default;
+      ${cfg.user} = default;
+    };
+  };
+
+  # For accurate stack trace
+  _file = ./default.nix;
+}

nixosModules/base/locale/default.nix

@@ -0,0 +1,45 @@
+{pkgs, ...}: {
+  fonts = {
+    fontconfig = {
+      enable = true;
+      defaultFonts = {
+        emoji = ["Noto Color Emoji"];
+        monospace = ["JetBrainsMono Nerd Font"];
+        sansSerif = ["Noto Nerd Font"];
+        serif = ["Noto Nerd Font"];
+      };
+    };
+
+    packages =
+      [
+        (pkgs.nerdfonts.override {
+          fonts = [
+            "JetBrainsMono"
+            "Go-Mono"
+            "Iosevka"
+            "NerdFontsSymbolsOnly"
+            "SpaceMono"
+            "Ubuntu"
+            "Noto"
+          ];
+        })
+      ]
+      ++ (builtins.attrValues {
+        inherit
+          (pkgs)
+          noto-fonts
+          noto-fonts-cjk-sans
+          noto-fonts-emoji
+          liberation_ttf
+          font-awesome
+          meslo-lgs-nf
+          jetbrains-mono
+          ubuntu_font_family
+          ;
+      });
+  };
+
+  # Select internationalisation properties.
+  i18n.defaultLocale = "en_CA.UTF-8";
+  console.useXkbConfig = true;
+}

nixosModules/base/locate/default.nix

@@ -0,0 +1,81 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (lib) concatStringsSep getName;
+
+  baseCfg = config.roles.base;
+  cfg = config.services.locate;
+
+  locateGroup = getName cfg.package.name;
+
+  locate = "${cfg.package}/bin/locate";
+  updatedb = "${cfg.package}/bin/updatedb";
+
+  database = "/var/lib/locate/locatedb";
+  pruneFS = concatStringsSep " " cfg.pruneFS;
+  pruneNames = concatStringsSep " " cfg.pruneNames;
+  prunePaths = concatStringsSep " " cfg.prunePaths;
+
+  updatedbBin = ''
+    ${updatedb} -o ${database} --prunefs "${pruneFS}" \
+      --prunepaths "${prunePaths}" --prunenames "${pruneNames}"
+  '';
+in {
+  users.users.${baseCfg.user}.extraGroups = [
+    locateGroup
+  ];
+
+  # TODO: add timer
+  systemd.services.locate = {
+    wantedBy = ["default.target"];
+    serviceConfig = {
+      User = baseCfg.user;
+      Group = locateGroup;
+      StateDirectory = "locate";
+      StateDirectoryMode = "0770";
+      ExecStart = updatedbBin;
+    };
+  };
+
+  home-manager.users.${baseCfg.user}.programs.bash.shellAliases = {
+    locate = "${pkgs.writeShellScriptBin "lct" ''
+      exec ${locate} -d ${database} "$@" 2> >(grep -v "/var/cache/locatedb")
+    ''}/bin/lct";
+
+    updatedb = updatedbBin;
+  };
+
+  services.locate = {
+    enable = true;
+    package = pkgs.mlocate;
+    localuser = null;
+    interval = "never";
+
+    prunePaths = [
+      "/var/lib/flatpak"
+
+      # Defaults
+      "/tmp"
+      "/var/tmp"
+      "/var/cache"
+      "/var/lock"
+      "/var/run"
+      "/var/spool"
+      "/nix/var/log/nix"
+    ];
+
+    pruneNames = [
+      "node_modules"
+
+      # Defaults
+      ".bzr"
+      ".cache"
+      ".git"
+      ".hg"
+      ".svn"
+    ];
+  };
+}

nixosModules/base/packages/default.nix

@@ -0,0 +1,126 @@
+self: {
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib) attrValues mkIf;
+
+  cfg = config.roles.base;
+in {
+  config = mkIf (cfg.enable) {
+    nixpkgs.overlays =
+      (map (i: self.inputs.${i}.overlays.default) [
+        "discord-overlay"
+        "grim-hyprland"
+        "nixpkgs-wayland"
+      ])
+      ++ (attrValues {
+        inherit
+          (self.overlays)
+          xdg-desktop-portal-kde
+          ;
+      });
+
+    environment.systemPackages =
+      (attrValues {
+        inherit
+          (self.packages.${pkgs.system})
+          pokemon-colorscripts
+          repl
+          ;
+
+        inherit
+          (pkgs.nodePackages)
+          undollar
+          ;
+
+        inherit (pkgs) alejandra;
+
+        # Archiving
+        inherit
+          (pkgs)
+          zip
+          unzip
+          p7zip
+          bzip2
+          gzip
+          gnutar
+          xz
+          ;
+
+        # File management
+        inherit
+          (pkgs)
+          findutils
+          diffutils
+          util-linux
+          which
+          imagemagick
+          ;
+
+        # Networking
+        inherit (pkgs.dig) dnsutils;
+        inherit
+          (pkgs)
+          arp-scan
+          openssh
+          rsync
+          wget
+          gnupg
+          ;
+
+        # Misc CLI stuff
+        inherit
+          (pkgs)
+          hydra-check
+          killall
+          nix-output-monitor
+          nix-melt
+          progress
+          tree
+          gnugrep
+          gnused
+          ;
+
+        # Expected Stuff
+        inherit
+          (pkgs)
+          hostname
+          man
+          perl
+          tzdata
+          ;
+      })
+      ++ [
+        # This could help as well: nix derivation show -r /run/current-system
+        (pkgs.writeShellApplication {
+          name = "listDerivs";
+          text = ''
+            exec nix-store --query --requisites /run/current-system | cut -d- -f2- | sort -u
+          '';
+        })
+
+        (pkgs.writeShellApplication {
+          name = "from";
+
+          runtimeInputs = attrValues {
+            inherit
+              (pkgs)
+              coreutils
+              which
+              ;
+          };
+
+          text = ''
+            for var do
+                realpath "$(which "$var")"
+            done
+          '';
+        })
+      ];
+  };
+
+  # For accurate stack trace
+  _file = ./default.nix;
+}

nixosModules/base/substituters/default.nix

@@ -0,0 +1,46 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib) foldl isList mergeAttrsWithFunc optionals unique;
+
+  mergeAttrsList = list:
+    foldl (mergeAttrsWithFunc (a: b:
+      if isList a && isList b
+      then unique (a ++ b)
+      else b)) {}
+    list;
+in {
+  environment.systemPackages = [
+    (pkgs.writeShellApplication {
+      name = "rebuild-no-cache";
+      runtimeInputs = [config.programs.nh.package];
+      text = ''
+        exec nh os switch -- --option binary-caches "https://cache.nixos.org" "$@"
+      '';
+    })
+  ];
+
+  nix = {
+    settings = let
+      mkSubstituterConf = url: key: {
+        substituters = [url];
+        trusted-public-keys = optionals (key != null) [key];
+      };
+    in
+      mergeAttrsList ([
+          (mkSubstituterConf "https://cache.nixos.org" "cache.nixos.org-1:6NCHdD59X431o0gWypbMrAURkbJ16ZPMQFGspcDShjY=")
+          (mkSubstituterConf "https://hyprland.cachix.org" "hyprland.cachix.org-1:a7pgxzMz7+chwVL3/pzj6jIBMioiJM7ypFP8PwtkuGc=")
+          (mkSubstituterConf "https://nix-gaming.cachix.org" "nix-gaming.cachix.org-1:nbjlureqMbRAxR1gJ/f3hxemL9svXaZF/Ees8vCUUs4=")
+          (mkSubstituterConf "https://nixpkgs-wayland.cachix.org" "nixpkgs-wayland.cachix.org-1:3lwxaILxMRkVhehr5StQprHdEo4IrE8sRho9R9HOLYA=")
+          (mkSubstituterConf "https://nix-community.cachix.org" "nix-community.cachix.org-1:mB9FSh9qf2dCimDSUo8Zy7bkq5CX+/rkCWyvRCYg3Fs=")
+          (mkSubstituterConf "https://viperml.cachix.org" "viperml.cachix.org-1:qZhKBMTfmcLL+OG6fj/hzsMEedgKvZVFRRAhq7j8Vh8=")
+          (mkSubstituterConf "https://cuda-maintainers.cachix.org" "cuda-maintainers.cachix.org-1:0dq3bujKpuEPMCX6U4WylrUDZ9JyUG0VpVZa7CNfq5E=")
+        ]
+        ++ optionals (!config.services.nix-serve.enable) [
+          (mkSubstituterConf "https://cache.nelim.org" "cache.nelim.org:JmFqkUdH11EA9EZOFAGVHuRYp7EbsdJDHvTQzG2pPyY=")
+        ]);
+  };
+}

nixosModules/default.nix

@@ -1,4 +1,5 @@
 self: {
+  base = import ./base self;
   borgbackup = import ./borgbackup;
   desktop = import ./desktop self;
   docker = import ./docker self.inputs.khepri;