common/default.nix

@@ -37,8 +37,6 @@
         rev = version;
         hash = "sha256-kgq3B+olx62bzGD5C6ighdAoDweLq+AebxVHcDnKH4w=";
       };
-
-      meta = removeAttrs o.meta ["knownVulnerabilities"];
     });
 
     # Edit nix.conf

devices/bbsteamie/modules/desktop/steam.nix

@@ -61,16 +61,19 @@ defaultSession: {
       };
     };
 
+    # Takes way too long to shutdown
+    systemd.services."decky-loader".serviceConfig.TimeoutStopSec = "5";
+
     # Misc Packages
     environment.systemPackages = [
       pkgs.steam-rom-manager
       pkgs.r2modman
-
       self.packages.${pkgs.system}.protonhax
 
-      # FIXME: Ryujinx ACNH crashes on Vulkan
+      # FIXME: Ryujinx ACNH crashes on OpenGL AND Vulkan
+      # https://github.com/Ryujinx/Ryujinx/issues/6993
       # https://github.com/Ryujinx/Ryujinx/issues/6708
-      pkgs.ryujinx
+      self.packages.${pkgs.system}.yuzu
     ];
   };
 

devices/nos/modules/docker/forgejo/images/act_runner.nix

@@ -1,8 +1,8 @@
 pkgs:
 pkgs.dockerTools.pullImage {
   imageName = "vegardit/gitea-act-runner";
-  imageDigest = "sha256:acc510a4754aa871dcaac69396055fea3117b5378a36efd9fbf3b3db542fa81a";
+  imageDigest = "sha256:674ef43377a9b802d53cbcf97ee128f95dd00cec817fb075950dcf7a618d880c";
-  sha256 = "12a9gw7nl5g4ji8jcg9w55a5zx7q9ny80bfk5qhl05yj7h6514ni";
+  sha256 = "1zd4w4vwij00ixdphv918g2js0ajimxdd43hwycfg4xqazmrvnpi";
   finalImageName = "vegardit/gitea-act-runner";
   finalImageTag = "dind-latest";
 }

devices/nos/modules/docker/freshrss/images/rss-bridge.nix

@@ -1,8 +1,8 @@
 pkgs:
 pkgs.dockerTools.pullImage {
   imageName = "rssbridge/rss-bridge";
-  imageDigest = "sha256:fada58f35c97d4e50ae045176339722b69397a6803a46c00799a96160db84092";
+  imageDigest = "sha256:833fa82afded7dd01514807009ccf66983bc21d874fc6acbe057a1fcda0f5e2d";
-  sha256 = "0q4hnmy21v9d5fjya0xn9yl4k5yzxm5irwp13scch6rbx2nn7gnc";
+  sha256 = "04gi7xn6335anaf908p3znc4d6llfv8yv4n7lc30mfxn7fh3nns9";
   finalImageName = "rssbridge/rss-bridge";
   finalImageTag = "latest";
 }

devices/nos/modules/docker/immich/images/machine-learning.nix

@@ -1,8 +1,8 @@
 pkgs:
 pkgs.dockerTools.pullImage {
   imageName = "ghcr.io/immich-app/immich-machine-learning";
-  imageDigest = "sha256:66f13f7fb1af555f9f1767c3dd5d404b7e5f486a272dc73af9e6480f541463dc";
+  imageDigest = "sha256:c0300d34fb275343c8e3b50796c9b10e6f33218e84c958386a218fbdceaeed65";
-  sha256 = "1i9i658b5k00r770f9ddbynz5jfgp9mql5z8ccdbld1fvl20493r";
+  sha256 = "083bwhkm9di3c3xz9yzp5hxmgm73wmlsqgjm11hjnwh3735zw54g";
   finalImageName = "ghcr.io/immich-app/immich-machine-learning";
-  finalImageTag = "v1.115.0";
+  finalImageTag = "v1.114.0";
 }

devices/nos/modules/docker/immich/images/server.nix

@@ -1,8 +1,8 @@
 pkgs:
 pkgs.dockerTools.pullImage {
   imageName = "ghcr.io/immich-app/immich-server";
-  imageDigest = "sha256:544fcfc41ce97833e33126e5041fb3b821e3db7bf405b54ac06689247a170a90";
+  imageDigest = "sha256:df4ae6d2bf8aa3ebd6370b42a667a007c5e7452a1cd2ab4c22fbaff9a69ffcbc";
-  sha256 = "10dc6srf1wd5w0zm0p977xfsbd73ljzl1lbld5wk3k3l2n1syzpd";
+  sha256 = "0pmx4cisxwa640ag36ls6gvasn0zg26yagp8sbr42yaaffwk9c4r";
   finalImageName = "ghcr.io/immich-app/immich-server";
-  finalImageTag = "v1.115.0";
+  finalImageTag = "v1.114.0";
 }

devices/nos/modules/docker/media/bazarr/images/bazarr.nix

@@ -1,8 +1,8 @@
 pkgs:
 pkgs.dockerTools.pullImage {
   imageName = "ghcr.io/linuxserver/bazarr";
-  imageDigest = "sha256:16a30c1ef7412f3781dc9635bd42798399601a9750f871cb68e5efb5545ce0f5";
+  imageDigest = "sha256:0364bb3d8d03cf0995036140322f6d0de78dd1924ba990499f67598f7c61ff62";
-  sha256 = "1lg7yakdvg7n9cyhqaf2ka4bj9a1902m6vbbkx1x9sx3igr4xlwy";
+  sha256 = "1i73c9m8nrmh0bz5hvyg71rmyjn06igxwbizhdmsvyrsjz8g0iwx";
   finalImageName = "ghcr.io/linuxserver/bazarr";
   finalImageTag = "latest";
 }

devices/nos/modules/docker/media/prowlarr/images/prowlarr.nix

@@ -1,8 +1,8 @@
 pkgs:
 pkgs.dockerTools.pullImage {
   imageName = "ghcr.io/linuxserver/prowlarr";
-  imageDigest = "sha256:c1318191d5211ac7462c754422eafe350ed0de61c4160065a420896068ec1ccc";
+  imageDigest = "sha256:9dd32e2270d174b07bd33a1f54e2b79e03ad944df62ed93efa08f4a381adc9a1";
-  sha256 = "1ddvrlh24x0blk1vkvxvxwi9hv4hqagy8fd4183vvpcf3c1rfpps";
+  sha256 = "1kx10is1zzwrgdz6y7i98jk3vmx7rv74dpgicimb1msdy9qm7m70";
   finalImageName = "ghcr.io/linuxserver/prowlarr";
   finalImageTag = "latest";
 }

devices/nos/modules/docker/media/sabnzbd/images/sabnzbd.nix

@@ -1,8 +1,8 @@
 pkgs:
 pkgs.dockerTools.pullImage {
   imageName = "ghcr.io/linuxserver/sabnzbd";
-  imageDigest = "sha256:cf7743af338e1cdfc97f6e6c605c8c45d737a4f268ab96ba6cec565134cea5e1";
+  imageDigest = "sha256:66576a72ecb80c8d9e8ebffd4699995b29bfff4aefba4c6eae14baac3cbf6716";
-  sha256 = "1d40g8q8wmwz5pdmh2rgmbm9ysj21vkcanzcjp5fljiz55fvmrpa";
+  sha256 = "10g4i9shbwgd9dswf5gx3jvnjcks0bn5mmadr39h8rfw3h31sq1v";
   finalImageName = "ghcr.io/linuxserver/sabnzbd";
   finalImageTag = "latest";
 }

legacyPackages/firefox-addons/generated-firefox-addons.nix

@@ -243,10 +243,10 @@
   };
   "sponsorblock" = buildFirefoxXpiAddon {
     pname = "sponsorblock";
-    version = "5.8.1";
+    version = "5.7";
     addonId = "sponsorBlocker@ajay.app";
-    url = "https://addons.mozilla.org/firefox/downloads/file/4349352/sponsorblock-5.8.1.xpi";
+    url = "https://addons.mozilla.org/firefox/downloads/file/4308094/sponsorblock-5.7.xpi";
-    sha256 = "001362fe0dfc6d5ea03fef4a2df75d6337d4ebd9cb829dff806920f5eab635e4";
+    sha256 = "05b7fadde5718cd44520a86e6b38b10816762df763767ef4bb879112ed77caae";
     meta = with lib; {
       homepage = "https://sponsor.ajay.app";
       description = "Easily skip YouTube video sponsors. When you visit a YouTube video, the extension will check the database for reported sponsors and automatically skip known sponsors. You can also report sponsors in videos. Other browsers: https://sponsor.ajay.app";

packages/README.md

@@ -14,3 +14,4 @@ This directory encompasses every derivations for packages exposed by my flake.
 | `protonhax`                    | [Github](https://github.com/jcnils/protonhax) |
 | `repl`                         | nix repl forked from [here](https://github.com/fufexan/dotfiles/blob/main/pkgs/repl/default.nix) |
 | `trash-d`                      | [Github](https://github.com/rushsteve1/trash-d) |
+| `yuzu`                         | Last working version of yuzu in nixpkgs |

packages/default.nix

@@ -39,4 +39,6 @@
   trash-d = pkgs.callPackage ./trash-d {
     inherit (inputs) trash-d-src;
   };
+
+  yuzu = pkgs.callPackage ./yuzu {};
 }

packages/yuzu/compat-list.nix

@@ -0,0 +1,20 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  ...
+}:
+stdenv.mkDerivation {
+  pname = "yuzu-compatibility-list";
+  version = "unstable-2024-02-26";
+
+  src = fetchFromGitHub {
+    owner = "flathub";
+    repo = "org.yuzu_emu.yuzu";
+    rev = "9c2032a3c7e64772a8112b77ed8b660242172068";
+    hash = "sha256-ITh/W4vfC9w9t+TJnPeTZwWifnhTNKX54JSSdpgaoBk=";
+  };
+
+  buildCommand = ''
+    cp $src/compatibility_list.json $out
+  '';
+}

packages/yuzu/default.nix

@@ -0,0 +1,18 @@
+{
+  qt6Packages,
+  makeScopeWithSplicing',
+  generateSplicesForMkScope,
+  ...
+}:
+(makeScopeWithSplicing' {
+  otherSplices = generateSplicesForMkScope "yuzuPackages";
+  f = self:
+    qt6Packages
+    // {
+      compat-list = self.callPackage ./compat-list.nix {};
+      nx_tzdb = self.callPackage ./nx_tzdb.nix {};
+
+      mainline = self.callPackage ./mainline.nix {};
+    };
+})
+.mainline

packages/yuzu/mainline.nix

@@ -0,0 +1,182 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nix-update-script,
+  wrapQtAppsHook,
+  autoconf,
+  boost,
+  catch2_3,
+  cmake,
+  compat-list,
+  cpp-jwt,
+  cubeb,
+  discord-rpc,
+  enet,
+  fmt,
+  glslang,
+  libopus,
+  libusb1,
+  libva,
+  lz4,
+  nlohmann_json,
+  nv-codec-headers-12,
+  nx_tzdb,
+  pkg-config,
+  qtbase,
+  qtmultimedia,
+  qttools,
+  qtwayland,
+  qtwebengine,
+  SDL2,
+  vulkan-headers,
+  vulkan-loader,
+  yasm,
+  zlib,
+  zstd,
+  ...
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "yuzu";
+  version = "1727";
+
+  src = fetchFromGitHub {
+    owner = "yuzu-emu";
+    repo = "yuzu-mainline";
+    rev = "mainline-0-${finalAttrs.version}";
+    hash = "sha256-DKIVXy3OGUfdw/mZtPzom40KU51CvXaV+KqRjQseDyk=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    cmake
+    glslang
+    pkg-config
+    qttools
+    wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    # vulkan-headers must come first, so the older propagated versions
+    # don't get picked up by accident
+    vulkan-headers
+
+    boost
+    catch2_3
+    cpp-jwt
+    cubeb
+    discord-rpc
+    # intentionally omitted: dynarmic - prefer vendored version for compatibility
+    enet
+
+    # vendored ffmpeg deps
+    autoconf
+    yasm
+    libva # for accelerated video decode on non-nvidia
+    nv-codec-headers-12 # for accelerated video decode on nvidia
+    # end vendored ffmpeg deps
+
+    fmt
+    # intentionally omitted: gamemode - loaded dynamically at runtime
+    # intentionally omitted: httplib - upstream requires an older version than what we have
+    libopus
+    libusb1
+    # intentionally omitted: LLVM - heavy, only used for stack traces in the debugger
+    lz4
+    nlohmann_json
+    qtbase
+    qtmultimedia
+    qtwayland
+    qtwebengine
+    # intentionally omitted: renderdoc - heavy, developer only
+    SDL2
+    # not packaged in nixpkgs: simpleini
+    # intentionally omitted: stb - header only libraries, vendor uses git snapshot
+    # not packaged in nixpkgs: vulkan-memory-allocator
+    # intentionally omitted: xbyak - prefer vendored version for compatibility
+    zlib
+    zstd
+  ];
+
+  # This changes `ir/opt` to `ir/var/empty` in `externals/dynarmic/src/dynarmic/CMakeLists.txt`
+  # making the build fail, as that path does not exist
+  dontFixCmake = true;
+
+  cmakeFlags = [
+    # actually has a noticeable performance impact
+    "-DYUZU_ENABLE_LTO=ON"
+
+    # build with qt6
+    "-DENABLE_QT6=ON"
+    "-DENABLE_QT_TRANSLATION=ON"
+
+    # use system libraries
+    # NB: "external" here means "from the externals/ directory in the source",
+    # so "off" means "use system"
+    "-DYUZU_USE_EXTERNAL_SDL2=OFF"
+    "-DYUZU_USE_EXTERNAL_VULKAN_HEADERS=OFF"
+
+    # don't use system ffmpeg, yuzu uses internal APIs
+    "-DYUZU_USE_BUNDLED_FFMPEG=ON"
+
+    # don't check for missing submodules
+    "-DYUZU_CHECK_SUBMODULES=OFF"
+
+    # enable some optional features
+    "-DYUZU_USE_QT_WEB_ENGINE=ON"
+    "-DYUZU_USE_QT_MULTIMEDIA=ON"
+    "-DUSE_DISCORD_PRESENCE=ON"
+
+    # We dont want to bother upstream with potentially outdated compat reports
+    "-DYUZU_ENABLE_COMPATIBILITY_REPORTING=OFF"
+    "-DENABLE_COMPATIBILITY_LIST_DOWNLOAD=OFF" # We provide this deterministically
+  ];
+
+  # Does some handrolled SIMD
+  env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isx86_64 "-msse4.1";
+
+  # Fixes vulkan detection.
+  qtWrapperArgs = [
+    "--prefix LD_LIBRARY_PATH : ${vulkan-loader}/lib"
+  ];
+
+  preConfigure = ''
+    # see https://github.com/NixOS/nixpkgs/issues/114044, setting this through cmakeFlags does not work.
+    cmakeFlagsArray+=(
+      "-DTITLE_BAR_FORMAT_IDLE=${finalAttrs.pname} | ${finalAttrs.version} (nixpkgs) {}"
+      "-DTITLE_BAR_FORMAT_RUNNING=${finalAttrs.pname} | ${finalAttrs.version} (nixpkgs) | {}"
+    )
+
+    # provide pre-downloaded tz data
+    mkdir -p build/externals/nx_tzdb
+    ln -s ${nx_tzdb} build/externals/nx_tzdb/nx_tzdb
+  '';
+
+  # This must be done after cmake finishes as it overwrites the file
+  postConfigure = ''
+    ln -sf ${compat-list} ./dist/compatibility_list/compatibility_list.json
+  '';
+
+  postInstall = ''
+    install -Dm444 $src/dist/72-yuzu-input.rules $out/lib/udev/rules.d/72-yuzu-input.rules
+  '';
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = ["--version-regex" "mainline-0-(.*)"];
+  };
+
+  meta = with lib; {
+    homepage = "https://yuzu-emu.org";
+    changelog = "https://yuzu-emu.org/entry";
+    description = "An experimental Nintendo Switch emulator written in C++";
+    mainProgram = "yuzu";
+    platforms = ["aarch64-linux" "x86_64-linux"];
+    license = with licenses; [
+      gpl3Plus
+      # Icons
+      asl20
+      mit
+      cc0
+    ];
+  };
+})

packages/yuzu/nx_tzdb.nix

@@ -0,0 +1,21 @@
+{
+  stdenv,
+  fetchurl,
+  unzip,
+  ...
+}:
+stdenv.mkDerivation rec {
+  pname = "nx_tzdb";
+  version = "221202";
+
+  src = fetchurl {
+    url = "https://github.com/lat9nq/tzdb_to_nx/releases/download/${version}/${version}.zip";
+    hash = "sha256-mRzW+iIwrU1zsxHmf+0RArU8BShAoEMvCz+McXFFK3c=";
+  };
+
+  nativeBuildInputs = [unzip];
+
+  buildCommand = ''
+    unzip $src -d $out
+  '';
+}